Do not use, republish, in whole or in part, without the consent of the Author. TheTAZZone policy is that Authors retain the rights to the work they submit and/or post…we do not sell, publish, transmit, or have the right to give permission for such…TheTAZZone merely retains the right to use, retain, and publish submitted work within it’s Network

Please refer to the original post as not all the script may be visible here.

Often times a rather useful utility is packaged as an EXE and you’d like to run it against multiple workstations. That’s easy enough, but can you do it with full accounting?

Here’s a pair of scripts (to be used together) that I’ve developed that will do just that. You’ll also need SOON.EXE, LOGEVENT.EXE, Microsoft Excel, and a text file containing the names of your workstations, one on each line (and administrative access from the command line).

2008.03.29 Edit: I added some error handling to the script to deal with machines that weren’t on the network (as I don’t always know which ones are and which ones aren’t at any given time). I also found that the functions using the WMI queries would hang on the odd workstation that didn’t have WMI configured correctly, so added error handling for that as well. Finally, I added a bit of feedback to the script, I like to know what the script is doing and where it is in execution. I’ve replaced deployEXE.VBS with the new script. (I’m making further changes to runEXE.VBS, I’ll post it when I’m done.)

2008.03.31 Edit: I modified the runEXE.VBS script to be OS aware, since the EVENTCREATE utility isn’t built into Windows 2000. Instead, the script makes use of the LOGEVENT.EXE utility (found in the Windows 2000 Resource Kit) located on a share. I also decided to add a bit of “debugging” output to a text file. If it’s unnecessary in your particular circumstance, feel free to remove it.

Script 1:

Code: Select all

' File Name:   deployEXE.VBS
' Script Name:   deployEXE.VBS
' Created:      2008.03.12
' Author:      Rob Durkin, STuladhar, Talen
' E-mail:
' ------------------------------------------------------------------------------
' ARGUMENTS :
'   None
' ------------------------------------------------------------------------------

' ------------------------------------------------------------------------------
' PURPOSE :
'   Runs an executable on a remote workstation from a network share and logs the
'   result to an Excel spreadsheet.
'   - The main script will copy the EXE file and one other VBS script to the
'   target machine.
'   - The main script will execute SOON.EXE (available via download from
'   Microsoft) to schedule the second VBS script on the target machine.
'   - The second script will execute the EXE and make an entry in the
'   application log based on success or failure.
'   - The main script will then follow up and parse through the application log
'   and check the result of the EXE.
'   * NOTE: Excel must be installed on the workstation the script is run from.
' ------------------------------------------------------------------------------
'
' ------------------------------------------------------------------------------
' REVISION HISTORY :
' Date:      2008.03.28
' Time:
' Issue:      Needed error handling in the event of unreachable workstations or
'            other issues that would cause a workstation not to respond.
' Solution:   Added workstation availability checks using ping as well as an On
'            Error trap around the call to the Functions using WMI queries.
'
' ------------------------------------------------------------------------------

Option Explicit

' ------------------------------------------------------------------------------
' FUNCTION LISTINGS
' ------------------------------------------------------------------------------
' Function:   getInstallStatus
' Created:   2007.12.26
' Author:   STuladhar
' Arguments: strSuccess & strFailed, defined in verifyInstall subroutine.
' ------------------------------------------------------------------------------
' Purpose:
'   Checks the installation status in the remote workstation Application log.
' ------------------------------------------------------------------------------
Function getInstallStatus(strSuccess, strFailed, strComputer)
Dim intCount, intFailed

intCount = getEventLogCount(strSuccess, strComputer)

If intCount > 0 Then
getInstallStatus = "P"
Else
intFailed = getEventLogCount(strFailed, strComputer)
If intFailed > 0 Then
getInstallStatus = "F"
Else
getInstallStatus = "U"
End If
End If
End Function

' ------------------------------------------------------------------------------
' Function:   getEventLogCount
' Created:   2007.12.26
' Author:   STuladhar
' Arguments: strWQL, success or failure WQL defined in verifyInstall subroutine.
' ------------------------------------------------------------------------------
' Purpose:
'   Counts the number of events in an event log matching specific criteria
'   defined via WQL query (see subVerifyInstall).
' ------------------------------------------------------------------------------
Function getEventLogCount(strWQL, strComputer)
Dim colLoggedEvents
Dim objWMISvc

Set objWMISvc = GetObject("winmgmts:" & "{(Security)}\\" & strComputer & _
"\root\cimv2")
Set colLoggedEvents = objWMISvc.ExecQuery(strWQL)

getEventLogCount = colLoggedEvents.Count
End Function

' ------------------------------------------------------------------------------
' Function:   getEventLogMsg
' Created:   2007.12.26
' Author:   STuladhar
' Arguments: strWQL, success or failure WQL defined in verifyInstall subroutine.
' ------------------------------------------------------------------------------
' Purpose:
'   Collects the event log descriptions for each event log entry collected
'   according to the WQL query in Function getEventLogCount.
' ------------------------------------------------------------------------------
Function getEventLogMsg(strWQL, strComputer)
Dim colLoggedEvents
Dim objEvent, objWMISvc
Dim strMsg

Set objWMISvc = GetObject("winmgmts:" & "{(Security)}\\" & strComputer & _
"\root\cimv2")
Set colLoggedEvents = objWMISvc.ExecQuery(strWQL)

For Each objEvent In colLoggedEvents
strMsg = strMsg & chr(13) & objEvent.Message
Next

' This is the length of the event log description. Change the length as
' necessary (the event log descriptions are defined in runEXE.VBS)
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
getEventLogMsg = Left(strMsg, 255)
End Function

' ==============================================================================
' SCRIPT BODY
' ==============================================================================
Dim a, b, DD, MM, YYYY, vDy, vMo
Dim errReturn, FileName, intProcessID
Dim strExcelFile, strCmd, strComputer, strDest01, strDest02, strFile01
Dim strFile02, strList, strPing, strText, strVBS, strWkstn
Dim objExcel, objExecObject, objFileCopy, objFSO, objSheet, objShell, objTxtFile

Const ForReading = 1, ForWriting = 2, ForAppending = 8

' Bind to the file system object
Set objFSO = CreateObject("Scripting.FileSystemObject")

' Bind to the shell object
Set objShell = CreateObject("WScript.Shell")

' Call the subroutines in the correct order (they're listed in alphabetical
' in the script body)
subGetDate
subCreateExcelWorkbook
subMain
' Pause the script for two and a half minutes (unnecessary if deploying to a
' large number of workstations)
WScript.Echo "Pausing script for 2 minutes and 30 seconds at " & Now
WScript.Sleep 150000
subVerifyInstall
subCleanUp

Sub subCleanUp
WScript.Echo "Beginning clean up..."

' Save the spreadsheet and close the workbook
objExcel.ActiveWorkbook.SaveAs strExcelFile
objExcel.ActiveWorkbook.Close
objExcel.Application.Quit

WScript.Echo "Clean up and script complete."
End Sub

Sub subCreateExcelWorkbook
' Define the filename for the Excel file, change to .XLSX if using Excel 2007
strExcelFile = YYYY & vMo & vDy & "deployEXE.XLS"

' Bind to the Excel application object
Set objExcel = CreateObject("Excel.Application")

' If Excel not found, exit script
If (Err.Number <> 0) Then
WScript.Echo "Excel application not found."
WScript.Quit
End If

' Create a new workbook
objExcel.Workbooks.Add

' Bind to and name the first worksheet in the workbook
Set objSheet = objExcel.ActiveWorkbook.Worksheets(1)
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
objSheet.Name = "Worksheet Name"

' Populate spreadsheet cells (column headings) with user-defined attributes
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
objSheet.Cells(1, 1).Value = "Target Computer"
objSheet.Cells(1, 2).Value = "Time"
objSheet.Cells(1, 3).Value = "Ping"
objSheet.Cells(1, 4).Value = "SOON Execution"
objSheet.Cells(1, 5).Value = "Utility Execution"
End Sub

' This subroutine gets the year, month and day for the purposes of building the
' Excel filename in the subroutine subCreateExcelWorkbook
Sub subGetDate
YYYY = Year(Now)
MM = Month(Now)
DD = Day(Now)

If MM < 10 Then
vMo = "0" & MM
Else
vMo = MM
End If

If DD < 10 Then
vDy = "0" & DD
Else
vDy = DD
End If
End Sub

Sub subMain
WScript.Echo "Deploying software..."

' Variable containing UNC path to workstation list text file
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strList = "\\SERVER\Share" & _
"\workstationList.TXT"

' Variable containing UNC path to executable that needs to be copied to
' remote machine
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strFile01 = "\\SERVER\Share" & _
"\Utility.EXE"

' Variable containing UNC path to script that needs to be copied to remote
' machine
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strFile02 = "\\SERVER\Share" & _
"\runEXE.VBS"

' Variable containing script that will launch executable on remote machine
strVBS = "runEXE.VBS"

' Open the text file containing the list of workstation names for reading
Set objTxtFile = objFSO.OpenTextFile(strList, ForReading)

' Set the Excel row variable to start on the second row
a = 2

' Begin looping through workstations
Do Until objTxtFile.AtEndOfStream
' Get machine name from text file (and remove any whitespaces)
strWkstn = Trim(objTxtFile.ReadLine())

' Ping the workstation, skipping it if it is unreachable on the network
strPing = "%comspec% /c ping -n 3 -w 1000 " & strWkstn & ""
Set objExecObject = objShell.Exec(strPing)

Do While Not objExecObject.StdOut.AtEndOfStream
strText = objExecObject.StdOut.ReadAll()

If InStr(strText, "Reply") > 0 Then
WScript.Echo "Starting on " & strWkstn & "..."

' UNC path to destination where executable and script needs to be
' copied to on the remote machine
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strDest01 = "\\" & strWkstn & "\C$" & _
"\Utility.EXE"
strDest02 = "\\" & strWkstn & "\C$" & _
"\runEXE.VBS"

' Copy the executable package to the target PC
Set objFileCopy = objFSO.GetFile(strFile01)
objFileCopy.Copy(strDest01), True

' Copy the VBScript to the target PC
Set objFileCopy = objFSO.GetFile(strFile02)
objFileCopy.Copy(strDest02), True

' Variable to hold the construction of the SOON command
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strCmd = """\\SERVER\Share\SOON.EXE"" \\" & _
strWkstn & " 120 ""cscript C:\" & strVBS & """"

' Variable to hold the error return code of the SOON command
errReturn = objShell.Run(strCmd)

' Time stamp the spreadsheet
objSheet.Cells(a, 2).Value = Now

' Evaluate the error return code of the SOON command and write
' results to Excel spreadsheet
If errReturn = 0 Then
objSheet.Cells(a, 1).Value = strWkstn
objSheet.Cells(a, 4).Value = "Success"
Else
objSheet.Cells(a, 1).Value = strWkstn
objSheet.Cells(a, 4).Value = "Failure"
End If
Else
WScript.Echo vbTab & strWkstn & " unreachable on network."
objSheet.Cells(a, 1).Value = strWkstn
objSheet.Cells(a, 2).Value = Now
objSheet.Cells(a, 3).Value = "Unreachable on network."
objSheet.Cells(a, 4).Value = "Failure"
End If
Loop

' Increment the Excel row variable to move to the next row down
a = a + 1
Loop

' Close the text file
objTxtFile.Close
WScript.Echo "Deployment complete."
End Sub

Sub subVerifyInstall
WScript.Echo "Verifying execution..."

Dim strEvtMsg, strFailed, strStatus, strSource, strSuccess
Dim intEvtCode01, intEvtCode02

' Define the Source being looked for in the Application log
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strSource = "Utility"

' Define the Event IDs being looked for in the Application log
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
intEvtCode01 = 990 ' Success
intEvtCode02 = 991 ' Failure

' WQL query definition to look for any entries from a specific source with a
' specific event code
strFailed = "Select * From Win32_NTLogEvent Where Logfile = 'Application'" _
& " and SourceName = '" & strSource & "' and EventCode = " & intEvtCode02
strSuccess = "Select * From Win32_NTLogEvent Where Logfile = 'Application'" _
& " and SourceName = '" & strSource & "' and EventCode = " & intEvtCode01

' Set the Excel row variable to start on the second row
b = 2
Do While objSheet.Cells(b, 1).Value <> ""
strComputer = objSheet.Cells(b, 1).Value

' Ping the workstation, skipping it if it is unreachable on the network
strPing = "%comspec% /c ping -n 3 -w 1000 " & strComputer & ""
Set objExecObject = objShell.Exec(strPing)

Do While Not objExecObject.StdOut.AtEndOfStream
strText = objExecObject.StdOut.ReadAll()

If InStr(strText, "Reply") > 0 Then
' Parse the application log based upon the value of the cell in the
' fourth column of the spreadsheet
Select Case objSheet.Cells(b, 4).Value
Case "Success"
WScript.Echo "Verifying execution on " & strComputer & "..."

On Error Resume Next
strStatus = getInstallStatus _
(strSuccess, strFailed, strComputer)

If strStatus = "F" Then
strEvtMsg = getEventLogMsg(strFailed, strComputer)
'objSheet.Cells(b, 5).Value = strEvtMsg
Else
strEvtMsg = getEventLogMsg(strSuccess, strComputer)
'objSheet.Cells(b, 5).Value = strEvtMsg
End If
objSheet.Cells(b, 5).Value = strEvtMsg
On Error Goto 0

Case Else
End Select
Else
WScript.Echo vbTab & strComputer & " unreachable on network."
End If
Loop

b = b + 1
Loop

WScript.Echo "Verification complete."
End Sub
' ==============================================================================
' END OF SCRIPT: deployEXE.VBS
' ==============================================================================

Script 2:

Code: Select all

' File Name:   runEXE.VBS
' Script Name:   runEXE.VBS
' Created:      2008.03.14
' Author:      Talen
' E-mail:
' ------------------------------------------------------------------------------
' ARGUMENTS :
'   None
' ------------------------------------------------------------------------------

' ------------------------------------------------------------------------------
' PURPOSE :
'   This script will run an executable on a workstation and create a custom entry
'   in the application log.
'   * NOTE: EVENTCREATE is a command line utility in Windows XP/Vista used to
'   create custom events in   the application log. See 'EVENTCREATE /?' for more
'   information. LOGEVENT is a command line utility found in the Windows 2000
'   Resource Kit and performs more or less the same function. See 'LOGEVENT /?'
'   for more information
' ------------------------------------------------------------------------------
'
' ------------------------------------------------------------------------------
' REVISION HISTORY :
' Date:
' Time:
' Issue:
' Solution:
'
' ------------------------------------------------------------------------------

' ==============================================================================
' SCRIPT BODY
' ==============================================================================
Option Explicit

Dim colItems, errReturn
Dim objFSO, objItem, objNet, objShell, objTxtFile, objWMI
Dim strCmd, strExe, strEvtFailure, strEvtSuccess, strOS, strRunEXEDebug
Dim strWkstn

Const ForWriting = 2

' Bind to the file system, network and shell objects
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objNet = CreateObject("WScript.Network")
Set objShell = CreateObject("WScript.Shell")

' Define the name of the debug output file
strRunEXEDebug = "C:\runEXEDebugOutput.TXT"

' Create the text file and close it
Set objTxtFile = objFSO.CreateTextFile(strRunEXEDebug)
objTxtFile.Close

' Open the text file for writing
Set objTxtFile = objFSO.OpenTextFile(strRunEXEDebug, ForWriting, True)

' Time stamp the debug file
objTxtFile.WriteLine(Now)

' Get the NetBIOS name of the workstation
strWkstn = objNet.ComputerName
objTxtFile.WriteLine("Workstation name: " & strWkstn)

' Define the executable and any parameters/arguments
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strExe = "Utility.EXE Parameters"

' Contruct the command to be run from the shell
strCmd = "C:\" & strExe
objTxtFile.WriteLine("Shell command: " & strCmd)

' Bind to the WMI service and query for the OS of the workstation
Set objWMI = GetObject("winmgmts:\\" & strWkstn & "\root\CIMV2")
Set colItems = objWMI.ExecQuery("SELECT * FROM Win32_OperatingSystem",,48)

' Set the strOS variable to the version number of the OS
For Each objItem in colItems
strOS = Left(objItem.Version, 3)
Next
objTxtFile.WriteLine("OS version number: " & strOS)

' Use the appropriate commands to create a custom application log entry based
' upon the installed OS (Vista is 6.0 and uses EVENTCREATE)
Select Case strOS
Case "5.0" ' Windows 2000
' Define the command to create a successful entry in the application log
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strEvtSuccess = "\\SERVER\Share\LOGEVENT.EXE -S I " & _
"-R Utility -E 990 -T 10000 ""Utility execution success."""

' Define the command to create a successful entry in the application log
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strEvtFailure = "\\SERVER\Share\LOGEVENT.EXE -S E " & _
"-R Utility -E 991 -T 10000 ""Utility execution failure."""

objTxtFile.WriteLine("OS version: Windows 2000")
Case "5.1" ' Windows XP
' Define the command to create a successful entry in the application log
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strEvtSuccess = "EVENTCREATE /T INFORMATION /SO Utility /ID 990 /L " & _
"APPLICATION /D ""Utility execution success."""

' Define the command to create an unsuccessful entry in the application
' log
' *** CHANGE TO SUIT NEEDS AS NECESSARY ***
strEvtFailure = "EVENTCREATE /T ERROR /SO Utility /ID 991 /L " & _
"APPLICATION /D ""Utility execution failure."""

objTxtFile.WriteLine("OS version: Windows XP")
End Select

' Execute the command and populate the errReturn variable with the result code
errReturn = objShell.Run(strCmd)
objTxtFile.WriteLine("errReturn: " & errReturn)

' Evaluate the result code and create the appropriate entry in the workstation
' application log
If errReturn = 0 Then
objTxtFile.WriteLine("Logging command: " & strEvtSuccess)
' Shell command to make success entry in application log.
objShell.Run strEvtSuccess
Else
objTxtFile.WriteLine("Logging command: " & strEvtFailure)
' Shell command to make failure entry in application log.
objShell.Run strEvtFailure
End If

objTxtFile.Close
' ==============================================================================
' END OF SCRIPT: deployEXE.VBS
' ==============================================================================

Just modify the scripts in the areas I’ve commented to get the script to work for you.

Do not use, republish, in whole or in part, without the consent of the Author. TheTAZZone policy is that Authors retain the rights to the work they submit and/or post…we do not sell, publish, transmit, or have the right to give permission for such…TheTAZZone merely retains the right to use, retain, and publish submitted work within it’s Network

Please refer to the original post as not all the script may be visible here.

I manage a *lot* of network devices (all of them Cisco), so I maintain a repository of configurations which are all text files. I devised a method to keep all the configurations straight, and essentially maintain a kind of change control system.

I have a folder on my system named “Network Device Configurations”. Inside this folder are folders named with the hostname of each individual device. Each device folder has subfolders named by year (e.g. 2008). Each year subfolder has twelve subfolders, 01 through 12, for each month of the year. Rather than create the folder structure by hand, I use the following script:

Code: Select all

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set WshShell = WScript.CreateObject("WScript.Shell")

strDeviceName = InputBox("Enter the device name:", "Network Device Name")

If strDeviceName = "" Then
WshShell.Popup "You must provide a device name!", 10, "Missing Device " & _
"Name!", 48
WScript.Quit
End If

' * * * Change This Line ! ! ! * * *
strTopLevelFldr = "C:\PathToYour\Network Device Configurations\" & _
strDeviceName
strYFldr = strTopLevelFldr & "\" & Year(Date)

If objFSO.FolderExists (strTopLevelFldr) Then
WshShell.Popup "Top level folder already exists and will not be created." & _
vbCrLf, 10, "Folder Exists!", 48
subCreateYFldr
Else
WshShell.Popup "Folder does not already exist and will be created." & _
vbCrLf, 10, "New Folder", 48
Set objFldr = objFSO.CreateFolder(strTopLevelFldr)
subCreateYFldr
End If

Sub subCreateYFldr
If objFSO.FolderExists (strYFldr) Then
WScript.Quit
Else
Set objFldr = objFSO.CreateFolder(strYFldr)
subCreateMFldrs
End If
End Sub

Sub subCreateMFldrs
intM = 1

Do Until intM = 10
strMFldr = strYFldr & "\0" & intM
Set objFldr = objFSO.CreateFolder(strMFldr)
intM = intM + 1
Loop

Do Until intM = 13
strMFldr = strYFldr & "\" & intM
Set objFldr = objFSO.CreateFolder(strMFldr)
intM = intM + 1
Loop
End Sub

WshShell.Popup "Creation of:" & vbCrLf & vbCrLf & strTopLevelFldr & _
vbCrLf & vbCrLf &   "and all subfolders complete.", 10, _
"Folders Created!", 48

Then, any and every time I edit a device configuration, the first thing I do is take a copy of the current configuration and save it to the appropriate folder and name it using the following convention:

Code: Select all

YYYYMMDD HHMM DeviceName Backup Config.TXT

When I’m done making any changes, I’ll save the new file using a similar convention:

Code: Select all

YYYYMMDD HHMM DeviceName New ACL.TXT

Generally using short, but descriptive nomenclature for whatever change I made. I also rarely save the entire config in this file, but usually just the changes made.

This is helpful in that I can review historical configurations and see what changes were made when (and the above naming convention keeps everything organized in chronological order when sorted by name).

Do not use, republish, in whole or in part, without the consent of the Author. TheTAZZone policy is that Authors retain the rights to the work they submit and/or post…we do not sell, publish, transmit, or have the right to give permission for such…TheTAZZone merely retains the right to use, retain, and publish submitted work within it’s Network

Please refer to the original post as not all the script may be visible here.

Sometimes I just need to quickly bomb through a directory.

Code: Select all

'# GLOBALS ##########################################################################
Dim   intCounter

'#########################################################################
Private Sub TraverseDir(objFolder)
Dim objFile
For Each objFile in objFolder.Files
WScript.Echo "Checking file: "& objFile.Path
intCounter = intCounter + 1
Next


Do not use, republish, in whole or in part, without the consent of the Author. TheTAZZone policy is that Authors retain the rights to the work they submit and/or post…we do not sell, publish, transmit, or have the right to give permission for such…TheTAZZone merely retains the right to use, retain, and publish submitted work within it’s Network

Please refer to the original post as not all the script may be visible here.

Enumerate the users of a AD Group. Very easy script, but can come in handy sometimes, save from having to use Users & Computers, also it will write the list of users to a file you can specify. You could make the script easier to use if you implement a prompt for entering the groupname you want to enumerate.

Code: Select all

strDom = "DomainName"
strGrp = "GroupName"

strMbrs = "Members of: " &  strGrp & vbCRLF

set objDom = GetObject("WinNT://" & strDom & "/" & strGrp)

for each objMbr in objDom.Members

strMbrs = strMbrs & objMbr.FullName & " (" & objMbr.Class &")" & vbCRLF

Next

Set oFilesys = CreateObject("Scripting.FilesystemObject")
Set oFiletxt = oFilesys.CreateTextFile("Pathtotextfile", True)
sPath = oFilesys.GetAbsolutePathName("Pathtotextfile")

sFilename= oFilesys.GetFileName(sPath)

oFiletxt.WriteLine(strMbrs)

oFiletxt.Close

'If you also want to see the users in a prompt enable following line

'Wscript.Echo strMbrs

Hope I didn’t type any errors, had to manually write it :s

Do not use, republish, in whole or in part, without the consent of the Author. TheTAZZone policy is that Authors retain the rights to the work they submit and/or post…we do not sell, publish, transmit, or have the right to give permission for such…TheTAZZone merely retains the right to use, retain, and publish submitted work within it’s Network

Please refer to the original post as not all the script may be visible here.

Much like the last script I posted, this script will deploy an MSI package to a group of workstations (provided in a text file). All you need is the list of workstations, the software package, and Microsoft Excel (and again, administrative access to each workstation from the command line).

Code: Select all

' File Name:   deployMSI.VBS
' Script Name:   deployMSI.VBS
' Created:      2008.03.28
' Author:      Rob Durkin, STuladhar, Talen
' E-mail:
' ------------------------------------------------------------------------------
' ARGUMENTS :
'   None
' ------------------------------------------------------------------------------

' ------------------------------------------------------------------------------
' PURPOSE :
' PURPOSE :
'   Installs an MSI on a remote workstation from a network share and logs the

Do not use, republish, in whole or in part, without the consent of the Author. TheTAZZone policy is that Authors retain the rights to the work they submit and/or post…we do not sell, publish, transmit, or have the right to give permission for such…TheTAZZone merely retains the right to use, retain, and publish submitted work within it’s Network

Please refer to the original post as not all the script may be visible here.

Adding this little chunk of code to your login script will change the “My Computer” name from “My Computer” to whatever the NetBIOS name of the (Windows) workstation is. Handy if you use a DNS-based remote access solution in the enterprise. Most users, without fail, can’t tell you the name of their workstation.

Code: Select all

Const MY_COMPUTER = &H11&

Set objNetwork = CreateObject("Wscript.Network")
objComputerName = objNetwork.ComputerName
Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.Namespace(MY_COMPUTER)
Set objFolderItem = objFolder.Self
objFolderItem.Name = objComputerName

I find it helpful.

Do not use, republish, in whole or in part, without the consent of the Author. TheTAZZone policy is that Authors retain the rights to the work they submit and/or post…we do not sell, publish, transmit, or have the right to give permission for such…TheTAZZone merely retains the right to use, retain, and publish submitted work within it’s Network

Please refer to the original post as not all the script may be visible here.

This script is designed to prevent a logoff from happening if a specific program is running, otherwise, if the program isn’t found, let the logoff process continue. I don’t know everyone’s script knowledge level so just in case I need to clarify I use the words process/program/executible interchangeably throughout the following explanation:

When the script is double-clicked it searches through the process list for an executible file. In the example below the executible is called vmware-vmx.exe. If this process is running on the computer the script will display a message to the user stating “x VMs are running. Please turn them off before continuing to logoff”. If the process is not found the script will logoff the user. In order for this to work you need to put a shortcut to this script in the Start menu (and/or desktop) and edit local group policy so that the logoff button no longer appears in the Start or Ctrl+Alt+Del menu. This will force users to click on the script whenever they want to logoff. You also need to change the process/program name to whatever program you want the script to search for. Replace where it says vmware-vmx and VMware with your program’s name. You can also use this script to prevent shutdown and restart. I made a comment towards the end of the script as to how.

Code: Select all

'************************************************************
' PREVENT LOGOFF SCRIPT
' Created: 6/14/2007
' Updated: 7/3/2007
'
' A big THANK YOU to Adam, Jaker, Guy Thomas, and Lisa
' ***********************************************************

‘ Require all variables to be declared before they can be used.
‘ This helps with debugging issues
Option Explicit

‘ Define all of the variables
Dim strComputer, objWMIService, colProcesses,
Dim objProcess, strList, VMcount

‘ Establish variables
strComputer = “.” ’setting strComputer to “.” connects to the local machine.
VMcount = 0 ’starts the process count at 0

‘ All WMI scripts begin by connecting to the Windows Management Instruments interface
Set objWMIService = GetObject(”winmgmts:” _
& “{impersonationLevel=impersonate}!\\” _
& strComputer & “\root\cimv2″)

‘ Get a collection of all running processes
Set colProcesses = objWMIService.ExecQuery(”Select * FROM Win32_Process”)

‘ Cycle through every currently running process
For Each objProcess in colProcesses
‘Check to see if the program is currently running
If objProcess.Name = “vmware-vmx.exe” Then
‘the program is running if the above statement is true.
VMcount = VMcount + 1 ‘Count the number of running processes
End If
Next
If VMcount > 0 Then
‘Build the message box text notifying the user of any running processes
strList = strList & VMcount _
& ” VMware process(es) running.” _
& “  Please power off before continuing to logoff.” & vbCr
‘This message box will only appear if the process was found
WSCript.Echo strList
Else
‘Create another variable to connect to the Windows shell service.
Dim objWSHShell
‘Connect to the Windows shell service
Set objWSHShell = CreateObject(”WScript.Shell”)
‘Execute the logoff command to logoff
objWSHShell.Run “shutdown -l” ‘change to -s to shutdown or -r to restart
End if
‘Quit the script
WScript.Quit

Do not use, republish, in whole or in part, without the consent of the Author. TheTAZZone policy is that Authors retain the rights to the work they submit and/or post…we do not sell, publish, transmit, or have the right to give permission for such…TheTAZZone merely retains the right to use, retain, and publish submitted work within it’s Network

Please refer to the original post as not all the script may be visible here.

This script should create a new user in AD as well as a new mailbox on an Exchange server. Use this one with caution, I haven’t really tested it yet.

Code: Select all

Option Explicit

Dim RootDSE, myDomain
'-------------------------------------------------------------------------------
Set RootDSE = GetObject("LDAP://RootDSE")
Set myDomain = GetObject("LDAP://" & RootDSE.Get("DefaultNamingContext"))

myDomainADSPath = myDomain.ADSPath      ' LDAP://DC=myDomain,DC=com
myDomainPath = MID(myDomain.ADSPath,8)   'DC=myDomain,DC=com

strTitle = "New User with Exchange Mailbox"
strUserName = InputBox("What is the name of the new user?", strTitle, "John Doe")
strSAM = InputBox("What will the be the user's SAMAccount name?", strTitle, "JDoe")

Do not use, republish, in whole or in part, without the consent of the Author. TheTAZZone policy is that Authors retain the rights to the work they submit and/or post…we do not sell, publish, transmit, or have the right to give permission for such…TheTAZZone merely retains the right to use, retain, and publish submitted work within it’s Network

Please refer to the original post as not all the script may be visible here.

This is a script I found that will check the storage limits on all mailboxes *not* using the default storage limits on an Exchange server. It outputs to a CSV file and is very handy for keeping track of users who’ve had their limits modified. If you’re an Exchange Admin, you know precisely what I’m talking about.

Code: Select all

' emailStorageLimts.vbs
' VBScript program to document users who do not have "Use Defaults"
' checked for their email storage.
' Copyright (c) 2005 Burt Johnson - bdjsoftware
'#######################################################################
Option Explicit

Dim objFSO, logFile
Dim oConnection1, oCommand1, rs, objUser
Dim Query

Const LDAP_TREE = "LDAP://DC=myDomain,DC=com"
Const ADS_SCOPE_SUBTREE   = 2
Const LOG_FILE   = "eMailStorageLimts.CSV"
'--------------------------------------------------------------------
' Set up log file
'--------------------------------------------------------------------
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set logFile = objFSO.CreateTextFile(LOG_FILE)
'--------------------------------------------------------------------
' Create the connection and command object.
'--------------------------------------------------------------------
Set oConnection1 = CreateObject("ADODB.Connection")
Set oCommand1 = CreateObject("ADODB.Command")
'--------------------------------------------------------------------
' Open the connection.
'--------------------------------------------------------------------
oConnection1.Provider = "ADsDSOObject"  ' This is the ADSI OLE-DB provider name
oConnection1.Open "Active Directory Provider"
'---------------------------------------------------------------------
' Create a command object for this connection.
'---------------------------------------------------------------------
Set oCommand1.ActiveConnection = oConnection1
'---------------------------------------------------------------------
' Compose a search string.
'----------------------------------------------------------------------
oCommand1.CommandText = "Select distinguishedName from '" & LDAP_TREE & "' WHERE objectCategory='Person' AND objectClass='user'"
oCommand1.Properties("Page Size") = 7000
oCommand1.Properties("Timeout") = 120
oCommand1.Properties("Searchscope") = ADS_SCOPE_SUBTREE
oCommand1.Properties("Cache Results") = False
'----------------------------------------------------------------------
' Execute the query.
'----------------------------------------------------------------------
Set rs = oCommand1.Execute
'----------------------------------------------------------------------
' Navigate the record set
'----------------------------------------------------------------------
MsgBox("Starting Search")

While Not rs.EOF

Query = "LDAP://" & rs.Fields("distinguishedName")
Set objUser = GetObject(Query)
If objUser.mDBUseDefaults = "False" Then
logFile.WriteLine("""" & objUser.distinguishedName & """,""" & objUser.mDBOverHardQuotaLimit & """,""" & objUser.mDBOverQuotaLimit & """,""" & objUser.mDBStorageQuota & """")
End If

rs.MoveNext
Wend

Set logFile = Nothing
Set oCommand1 = Nothing
Set oConnection1 = Nothing
Set rs = Nothing
Set objUser = Nothing

msgBox("Done Searching")

The only thing that really needs editing is the LDAP name of the domain you’re running the script in. The line towards the bottom in the If statement is one long line, even though it may wrap on your screen.

Do not use, republish, in whole or in part, without the consent of the Author. TheTAZZone policy is that Authors retain the rights to the work they submit and/or post…we do not sell, publish, transmit, or have the right to give permission for such…TheTAZZone merely retains the right to use, retain, and publish submitted work within it’s Network

Please refer to the original post as not all the script may be visible here.

Speaking of backups, how many of you backup your workstations at home regularly? Most of us probably should, but the scheduler provided for NTBackup doesn’t work very well, and who can afford a high-end solution like Backup Exec? Microsoft has added a regular backup feature to OneCare Live, but it’s limited as to where you can target the backups. Fortunately, you can use VBScript to control NTBackup (and even add logging), and then use the Task Scheduler to run the script on a schedule.
Here’s the script with comments that should explain most everything. If you have any other questions, PM me or start a new thread in the Scripting forum.

Code: Select all

Option Explicit

Dim objFSO
Dim objShell
Dim strOutlook
Dim bksFile
Dim bkfFile
Dim strBackup
Dim strLogFile
Dim oldLogFile
Dim objWrite
Dim objFile
Dim strMonth
'###################################################################
Set objFSO = CreateObject("Scripting.FileSystemObject")